*----------------------------*
*Cinevox - programa de acesso ao portal Cine Brasil para usuários de Dosvox (www.cinebrasil.net.br);
*módulo de notificação automática;
*Autor da versão 2.0 em Scriptvox: Fabiano Ferreira - em Janeiro de 2025;
*Autor da versão 1.0 em Python: Carlos Christian - em Janeiro de 2025;
*----------------------------*

tela minimizada
seja $uid "temp\uid"

remove $uid &
seja $baseurl "162.220.14.188"
seja $porta 6001
seja $recurso "/notificacoes "
seja $metodo "GET "

seja $versao_http "HTTP/1.1"
seja $useragent "Cinevox"

internet inicia
seja x 0
@checnot
conecta #0 $baseurl $porta &

escreve #0 $metodo $recurso $versao_http
escreve #0 "Host: "$baseurl
escreve #0 "User-Agent: "$useragent
escreve #0 "Accept: */*"
escreve #0 "Connection: Close"
escreve #0 ""

le #0 l
enquanto l <> ""
le #0 l
fim enquanto

le #0 l
seja $notas l

seja p pos "{""id"":" l
soma p 6
seja t tamanho l
copia l l p t
seja p pos "," l
subtrai p 1
copia l l 1 p

busca b $uid
se b = ""
abre #1 $uid &
escreve #1 l
fecha #1
senão
abre #1 $uid
le #1 x
fecha #1
se l > x toca "som\cvnovo.wav"&
se l > x remove $uid
se l > x abre #1 $uid&
se l > x escreve #1 l
se l > x fecha #1
se l > x chama @notifica
fim se
espera 5

existeprog "cinevox.exe" x
se x = 0 termina mudo
desvia @checnot

@notifica
seja l $notas
seja p pos "mensagem"":""" $notas
soma p 13
seja t tamanho $notas
copia $notas $notas p t
seja p pos """" $notas
subtrai p 1
copia $notas $notas 1 p
seja p pos "\n" $notas
subtrai p 1
copia $notas $notas 1 p

concatena $notas " - em "
seja p pos "dataHora"":""" l
soma p 11
seja t tamanho l
copia l l p t
seja p pos """" l
subtrai p 1
copia l l 1 p
chama @convertedatahora
concatena $notas $data
concatena $notas " "
concatena $notas $hora
utf8paraansi $notas
escreve $notas
retorna

@convertedatahora
seja $data ""
copia $ano l 1 4
copia $mes l 6 7
copia $dia l 9 10
copia $hora l 12 19
concatena $data $dia
concatena $data "/"
concatena $data $mes
concatena $data "/"
concatena $data $ano
retorna
