chama @update
tela minimizada
existeprog "cinevox.exe" x
enquanto x = 1
espera 5
existeprog "cinevox.exe" x
fim enquanto
bipa

seja $recurso "/desconectar "
seja $baseurl "162.220.14.188"
seja $porta 6000
seja $metodo "DELETE "
seja $useragent "Cinevox"
seja $versao_http "HTTP/1.1"
internet inicia
conecta #0 $baseurl $porta

escreve #0 $metodo $recurso $versao_http
escreve #0 "Host: "$baseurl
escreve #0 "User-Agent: "$useragent
escreve #0 "Accept: */*"
escreve #0 "Connection: Close"
escreve #0 ""
le #0 r
copia r r 10 12
se r <> 200
Escreve "A desconexão não pôde ser registrada."
Escreve "Erro "r
fim se
fecha #0
internet termina
termina mudo

@update
busca b "cinevox_version.txt"
se b = "" retorna

abre #1 b
le #1 $versao
chama @lenoticias
fecha #1

seja $recurso "/gdrive/software/fabiano/cinevox_version.txt"
seja $porta 443
seja $metodo "GET "
seja $versao_http " HTTP/1.1"
seja $host "www.cinebrasil.net.br"
seja $useragent "Cinevox"
internet inicia
conecta ssl #1 $host $porta
escreve #1 $metodo $recurso $versao_http
escreve #1 "Host: "$host
escreve #1 "User-Agent: "$useragent
escreve #1 "Accept: */*"
escreve #1 "Connection: Close"
escreve #1 ""
le #1 r
enquanto não r = ""
le #1 r
fim enquanto
le #1 $ultima_versao
le #1 $ultima_versao
fecha #1
internet termina
se $ultima_versao > $versao chama @atualizacinevox
retorna

@atualizacinevox
seja $nomearq "cinevox-"
concatena $nomearq $ultima_versao
concatena $nomearq "-update.7z"

seja $url "https://www.cinebrasil.net.br/gdrive/software/fabiano/"
concatena $url $nomearq

trazdarede $url $nomearq 0 "" "Cinevox" x

seja $extraipacote "7za x "
concatena $extraipacote $nomearq
concatena $extraipacote " -y"
executa "taskkill /f /im cinevox.exe"&&
existeprog "taskkill.exe" x
enquanto x = 1
espera ms 500
existeprog "taskkill.exe" x
fim enquanto

executa "taskkill /f /im cinevox_mon.exe"&&
existeprog "taskkill.exe" x
enquanto x = 1
espera ms 500
existeprog "taskkill.exe" x
fim enquanto

executa $extraipacote &&
existeprog "7za.exe" x
enquanto x = 1
espera ms 500
existeprog "7za.exe" x
fim enquanto
remove $nomearq
executa "cinevox.exe"&
termina mudo

@lenoticias
titulo "Cinevox Check"
tela normal
captura ativa j
enquanto j <> "Cinevox Check"
bipa
aciona "alt+esc"
captura ativa j
fim enquanto

le #1 l
se l =* "*" retorna
checa c
enquanto c = 0
se l = "."
bipa 1
le mudo k &
senão
se l =* "["
seja p pos "]" l
subtrai p 1
copia l l 2 p
toca l
senão
escreve l
fim se
le #1 l
checa c
fim enquanto
fecha #1

seja z "cinevox_version_temp.txt"
replica b z
remove b &
abre #2 b &
abre #1 z
le #1 l
escreve #2 l
le #1 l
checa c
enquanto c = 0
escreve #2 "*"l
le #1 l
checa c
fim enquanto
fecha #2
fecha #1
remove z
dir troca "som\update"
busca x "*.*"
enquanto x <> ""
remove x
busca x proximo
fim enquanto
dir troca ".."
dir troca ".."
abre #1 b
retorna
